One thing to remember is that GitHub is not Apache’s main source control solution.  Apache still uses Subversion and as such doesn’t use the same concepts used with Git or GitHub.  For instance, if you were to fork the Flex repository, you could clone it and do all your changes and send over pull requests but the powers that be won’t accept them (as far as I heard, that might change).

The best thing to do would be to clone the repository directly from the Flex project so that you can easily stay up to date with the changes.  Then apply your changes locally and create a patch file by doing git format-patch master --stdout > your_patch_name.patch.

After the patch file has been created, you need to attach it to a Jira ticket (need to register for an account). If one hasn’t been made already, create a new one and be descriptive as to what was done, why it needs to be done and maybe even your thoughts behind it; the more information the better. You should hear from one of the community in the next week or so about the status of your patch.

That’s all there is to it. Now go forth and contribute!

All of this was recorded and can be viewed on UStream.  Video after the break.

Let’s give a quick example of a simple problem: You need to find the index of a string within a 2D array and do something with that index.  Here’s how I would do it normally:

private function findIndex(text:String):void
{
	var row:Array;
	var index:Point;
	for(var y:uint = 0, ylen:uint = array.length; y<ylen; y++)
	{
		row = array[y];
		for(var x:uint = 0, xlen:uint = row.length; x<xlen; x++)
		{
			if(row[x] == text)
			{
				index = new Point(x,y);
				break;
			}
		}
		if(index)
		{
			break;
		}
	}
	// Do something with index
}

You’ll notice that within the example, the second I find the index, I break out of the loops to reduce the run time of the function. The external loop always looks to see if ‘index’ is not null and breaks out if it is. I’ve never liked this approach because it adds more code than needed and sometimes its not as easy as just checking if a variable is not null. You could always use ‘return’ if your function is done with its purpose, but that’s not always possible.

The alternative to this is using label statements. What you can do is simply ‘label’ your loops and then when you want to break, you can specify which loop that needs to be broken. Take our current example and let’s add label statements in it:

private function findIndex(text:String):void
{
	var row:Array;
	var index:Point;
	outer:for(var y:uint = 0, ylen:uint = array.length; y<ylen; y++)
	{
		row = array[y];
		for(var x:uint = 0, xlen:uint = row.length; x<xlen; x++)
		{
			if(row[x] == text)
			{
				index = new Point(x,y);
				break outer;
			}
		}
	}
	// Do something with index
}

That is much better and cleaner. I’ve seen this done before in Java, but I have never encountered or read about it for Actionscript. This method can also be used with the ‘continue’ operator so that it skips the rest of the code to the next iteration or with block statements like so:

doSomething: {
	var x:uint = index.x;
	if(x > 100)
	{
		break doSomething;
	}
	trace(x);
}

I don’t think I would ever use it with block statements since these could be simply replaced with ‘if’ statements, but knowing about it can be beneficial. I know I will be using label statements in nested loops from now on.